how query by column number with awk

You need to tell awk to use both , and : as field separators. Note that this will change the numbering of the fields (because both field separators are applied to each input line). For example:

$ awk -F '[:,]' '{ t = $2*3600 + $3*60 + $4 }
                 NR > 1 { printf "%.6fn", t-p }
                 { p=t }' inputfile
13.000000
7.000000

Note that this does not calculate time differences across different days. To do that, you’d need to parse the combined date and time into a time_t value (i.e. seconds since the epoch, Midnight on Jan 1 1970). For example, with GNU awk, using the mktime() function:

$ awk -F '[:,]' '{
                    # extract the year, month, and day from the first field
                    y = substr($1,1,4);
                    m = substr($1,5,2);
                    d = substr($1,7,2);
                    # create a space-separated datespec string, combining y,m,d with
                    # hours, minutes, and seconds from fields 2, 3, and 4
                    datespec = y " " m " " d " " $2 " " $3 " " $4;
                    # convert it to seconds since the epoch
                    t = mktime(datespec)
                  }
                  NR > 1 { printf "%.6fn", t-p }
                  { p=t }' inputfile
13.000000
7.000000

Run man awk and search for mktime for a summary on how this function works.